Ŝablono:E-koloroj/dokumentado

Ĉi tiu ŝablono servas por traduki Esperantan kolornomon al HTML-e kaj CSS-e laŭnorman Anglaĵon. Ĉi-cele servas la paĝo Kolornomoj por TTT, kiun Aŭka programo uzas por generi ĉi tiun ŝablonon. Se por koloro ne ekzistas CSS-nomo, ĝi liveras deksesume la #RGB-valoron.

La ŝablono estas uzata subŝablone de Ŝablono:Paletro pala kaj Ŝablono:Paletro ombra. Aliflanke, ĝi povas esti uzata sendepende. La ŝablono klopodas akcepti ĉiujn eblajn formuladojn por koloro, tamen la radika kombino mem devas ĝusti. Uskleco neniel rolas.

Uzado

{{Kolornomoj|noktomezoBlua}}

{{Kolornomoj|roza}}

{{Kolornomoj|mare verda}} 

{{Kolornomoj|malva}}

Parametroj

Ne nomitaj parametroj

1. Kolornomo en Esperanto por traduki Anglen. (Pravaloro: neniu, lasas nekonataĵon ne ŝanĝita)

Nomitaj parametroj

neniu

Ekzemploj

MidnightBlue

Pink

SeaGreen

#E0B0FF

Aŭkaĵo por produkti tion

BEGIN 	{FS="|"; ekster=0; print "<includeonly>{{#switch:{{lc:{{{1}}}}}";}

/Ankro[|]hex_please/ {ekster=1;}


NF==8 && $0~/^[|]/ {
	gsub(" ","");
	gsub("<tt>&nbsp;&nbsp;","");
	gsub("<tt>&nbsp;","");
	gsub("<tt>","");
	gsub("</tt>","");
	gsub("&nbsp;&nbsp;&nbsp;",",");
	gsub("&nbsp;&nbsp;",",");
	gsub("&nbsp;",",");


	gsub(",","",$6);

	s=variantoj($4);

	if (ekster==1)
		print "|" tolower($2) s "=#" $6
	else
		print s "=" $2;		
	}

END	{print "|{{{1}}}}}</includeonly><noinclude>{{Dok}}</noinclude>";}


function variantoj(s, s1, s2, t, t1, t2, t3, n, c)
{
	t="|" s;
	t3=substr(s,1,length(s)-1)
	t=t "|" t3 "e";
	t=t "|" t3 "o";

	s1=substr(s,1,1);
	s2=substr(s,2);
	n=match(s2, /[[:upper:]]/);
	if(n>0)
	{
		t1=s1 substr(s2,1,n-1);
		t2=substr(s2,n);
		c=substr(t1,length(t1));
		if (c=="o")
			t1=substr(t1,1,length(t1)-1);
		t=t "|" t1 "e " t2;
		t=t "|" t1 "e" t2;
		if (c!="o" && c!="l")
			t=t "|" t1 "o" t2;
		t=t "|" t1 "a " substr(t2,1,length(t2)-1) "o";
		if (t1=="Pal" && t2!="Verda")
		{
			t=t "|" "Hel" t2;
			t=t "|" "Hele " t2;
			t=t "|" "Hele" t2;
			t=t "|" "Hela " substr(t2,1,length(t2)-1) "o";
		}
		if (t1=="Hel" && t2!="Verda")
		{
			t=t "|" "Pal" t2;
			t=t "|" "Pale " t2;
			t=t "|" "Pale" t2;
			t=t "|" "Pala " substr(t2,1,length(t2)-1) "o";
		}
	}
	else
	{
		t=t "|" substr(s,1,length(s)-1) "kolora";
		t=t "|" substr(s,1,length(s)-1) "okolora";
	}
	return tolower(t);		
}

La programo akceptas la enhavon de la tuta sekcio, do kun la tekstaĵoj ktp. Ĝi mem elsarkas la gravajn liniojn el la tabelo. Evidente, oni ne plu metu iujn pliajn tabelojn en la sekcion.